#version 330 core

#ifndef LIGHT_GLSL
#define LIGHT_GLSL

struct Material {
	vec3 ambient;
	vec3 diffuse;
	vec3 specular;
	sampler2D ambient_map;
	sampler2D diffuse_map;
	sampler2D specular_map;
	float shininess;
};

struct PointLight {
	vec3 position;
	vec3 diffuse;
	vec3 specular;
	float constant;
	float linear;
	float quadratic;
};

vec3 calc_ambient_light(in Material material, in vec2 texture_coords)
{
	return vec3(texture(material.ambient_map, texture_coords)) * material.ambient;
}

vec3 calc_diffuse_light(
	in Material material,
	in PointLight light,
	in vec3 light_dir,
	in vec3 norm,
	in vec2 texture_coords
)
{
	float diff = max(dot(norm, light_dir), 0.0);

	return light.diffuse * (
		diff * (vec3(texture(material.diffuse_map, texture_coords)) * material.diffuse)
	);
}

vec3 calc_specular_light(
	in Material material,
	in PointLight light,
	in vec3 light_dir,
	in vec3 norm,
	in vec3 view_pos,
	in vec3 frag_pos,
	in vec2 texture_coords
)
{
	vec3 view_direction = normalize(view_pos - frag_pos);

	vec3 reflect_direction = reflect(-light_dir, norm);

	float spec =
		pow(max(dot(view_direction, reflect_direction), 0.0), material.shininess);

	return light.specular * (
		spec * (vec3(texture(material.specular_map, texture_coords)) * material.specular)
	);
}

float calc_attenuation(in PointLight point_light, in vec3 position)
{
	float light_distance = length(point_light.position - position);

	return 1.0 / (point_light.constant + point_light.linear
		* light_distance + point_light.quadratic
		* pow(light_distance, 2));
}

vec3 calc_point_light(
	in PointLight light,
	in vec3 frag_pos,
	in vec3 normal,
	in vec2 texture_coords,
	in vec3 view_pos,
	in Material material
)
{
	vec3 light_direction = normalize(light.position - frag_pos);
	vec3 norm = normalize(normal);

	vec3 diffuse_light = calc_diffuse_light(
		material,
		light,
		light_direction,
		norm,
		texture_coords
	);

	vec3 specular_light = calc_specular_light(
		material,
		light,
		light_direction,
		norm,
		view_pos,
		frag_pos,
		texture_coords
	);

	float attenuation = calc_attenuation(light, frag_pos);

	diffuse_light *= attenuation;
	specular_light *= attenuation;

	return diffuse_light + specular_light;
}

#endif